***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Aug 30, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt PZS513V9BCH A K
.param
+vc0 = 3.046e-11	 vc1 = 3.053e-10	 vc2 = 8.205e-1		 vc3 = 5.651e-11	 vc4 = 10
+tc1 = 9.351e-3		 tc2 = 2.021e-3		 tc3 = 4.941e-3		 tc4 = 1.721e-3	
.func irpwr(v) {(vc0+vc1*v^vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*v^vc4)*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K zener
g1 K A value = {irpwr(v(K,A))}
.model zener d
***** flag parameter ***
+level = 1   
***** dc model parameter ***
+ is = 4.662e-16	   n = 9.981e-1		  rs = 1.690e-1		ikf = 1.128e-1
+ibv = 50e-6		 nbv = 2.8		  bv = 3.9
***** capacitance parameter ***
+cjo = 1.263e-10	   m = 3.231e-1		  vj = 6.917e-1
+ fc = 0.5                      
***** temperature coefficient ***
+tnom = 25		  eg = 1.095		 xti = 3
+trs1 = 8.527e-5	trs2 = -2.344e-6	tbv1 = -3.065e-4	tbv2 = -8.071e-7	tikf = 4.567e-3
.ends PZS513V9BCH
*$
